DevOps自动归档实践

本文指导用户使用悦库网盘的yshell命令行客户端，实现对DevOps产物（测试包和发布包）自动归档到悦库网盘中。前提是需要安装并使用悦库服务端，可以查看《悦库管理员手册》进行安装。

由于目前yshell不支持上传目录下所有文件功能，因此需要逐个上传，我们后续会逐渐增强功能！

 @echo off
 rem 脚本功能描述
 rem 参数为归档类型：test(测试包)或release(发布包)，使用举例：ydiskArchive.bat test
 rem   每日构建执行完成后，将所有生成的测试安装包上传到悦库内盘公共空间的"sprint"目录中。
 rem   自动发布执行完成后，将所有发布包上传到悦库内盘公共空间的"release"目录中。
 rem ysh执行失败会返回非0值，应该将这个值从脚本中返回，这样Jenkins可以识别错误并中断构建任务。
 
 rem 切换到当前脚本所在目录
 cd "%~dps0"
 %~d0
 
 rem 归档方式为test或release
 set ArchiveType=%1
 
 if "%ArchiveType%"=="" (
  echo "请输入归档类型参数，test或release ！".
  exit /b 1
 )
 echo Archive type is %ArchiveType%
 
 rem 获取当前版本号
 set /p CurrVersion=<../version.txt
 rem 获取当前git分支
 set CurrBranch=""
 for /F %%i in ('git rev-parse --abbrev-ref HEAD') do (set CurrBranch=%%i)
 echo version is %CurrVersion% , git branch is %CurrBranch% 
 
 rem 构建悦库网盘目标路径
 set YDiskPath=""
 if "%ArchiveType%"=="test" ( 
 set YDiskPath="/公共空间/悦库安装包/sprint/%CurrBranch%" 
 )
 if "%ArchiveType%"=="release" ( 
 set YDiskPath="/公共空间/悦库安装包/release/%CurrVersion%" 
 )
 echo YDiskPath is %YDiskPath%
 
 rem 配置悦库登录地址、用户名称和密码
 ysh user -u http://192.168.0.102:2020 -a jenkens -p 666666
 if not %errorlevel% == 0 (exit /b %errorlevel%)
  
 rem 在悦库中以分支名称创建文件夹。使用-p参数，如果空间或文件夹不存在会自动级联创建。
 ysh mkdir -p %YDiskPath% 
 
 rem 上传所有安装包，如果包已经存在则会覆盖。要获取历史包可以在该文件的历史版本信息中下载。
 ysh put -f "../output/ydisks_win64_free.exe" %YDiskPath% 
 if not %errorlevel% == 0 (exit /b %errorlevel%)
 ysh put -f "../output/ydisks_docker_x64.tar.gz" %YDiskPath% 
 if not %errorlevel% == 0 (exit /b %errorlevel%)
 ysh put -f "../output/ydisks_docker_arm64.tar.gz" %YDiskPath% 
 if not %errorlevel% == 0 (exit /b %errorlevel%)
 ysh put -f "../output/ydisks_cluster_docker_x64.tar.gz" %YDiskPath% 
 if not %errorlevel% == 0 (exit /b %errorlevel%)
 ysh put -f "../output/ydisks_cluster_docker_arm64.tar.gz" %YDiskPath% 
 if not %errorlevel% == 0 (exit /b %errorlevel%)
 exit /b 0